İşaretçilerin Arduino'da kullanımı?

C++
1 
Bir işaretçi bir değişkenin adresini sakladığı için bir değer dolaylı yoldan
erişmek mümkündür.x’in bir tam sayı değişken olduğunu kabul edelim. px
değişkeni ise bu x değişkenine işaret eden bir işaretçi değişken olsun. &
operatörü bir nesnenin adresini bulmamızı sağlar.
Px = &x;
İşlemi x’in adresini px değişkenine atar. Artık px x değerine bir işaretçidir.
& operatörü sadece değişkenlere, dizilere ve veri yapılarına
uygulanabilirler. &(x+1) ve &3 şeklindeki kullanımlar geçersizdir. Register
niteleyicisi ile tanımlanmış bir değişkeninde adresini almak geçersiz
işlemdir.
* operatörü de yanındaki ifadenin bir işaretçi olduğunu anlatır ve bu
adresin ifade ettiği yerdeki değişkeni anlatır. Eğer adı y olan bir int
değişken olsun
y= *px;
ifadesi y değerine px’in gösterdiği yerdeki değeri atar. Yani:
px = &x;
y = *px
ifadesi
y = x;
ifadesine denk bir işlem yapar

Bu metni baz alarak

// nrf24_server.pde
// -*- mode: C++ -*-
// Example sketch showing how to create a simple messageing server
// with the RH_NRF24 class. RH_NRF24 class does not provide for addressing or
// reliability, so you should only use RH_NRF24  if you do not need the higher
// level messaging abilities.
// It is designed to work with the other example nrf24_client
// Tested on Uno with Sparkfun NRF25L01 module
// Tested on Anarduino Mini (http://www.anarduino.com/mini/) with RFM73 module
// Tested on Arduino Mega with Sparkfun WRL-00691 NRF25L01 module

#include <SPI.h>
#include <RH_NRF24.h>

// Singleton instance of the radio driver
RH_NRF24 nrf24;
// RH_NRF24 nrf24(8, 7); // use this to be electrically compatible with Mirf
// RH_NRF24 nrf24(8, 10);// For Leonardo, need explicit SS pin
// RH_NRF24 nrf24(8, 7); // For RFM73 on Anarduino Mini

void setup() 
{
  Serial.begin(9600);
  while (!Serial) 
    ; // wait for serial port to connect. Needed for Leonardo only
  if (!nrf24.init())
    Serial.println("init failed");
  // Defaults after init are 2.402 GHz (channel 2), 2Mbps, 0dBm
  if (!nrf24.setChannel(1))
    Serial.println("setChannel failed");
  if (!nrf24.setRF(RH_NRF24::DataRate2Mbps, RH_NRF24::TransmitPower0dBm))
    Serial.println("setRF failed");    
}

void loop()
{
  if (nrf24.available())
  {
    // Should be a message for us now   
    uint8_t buf[RH_NRF24_MAX_MESSAGE_LEN];
    uint8_t len = sizeof(buf);
    if (nrf24.recv(buf, &len))
    {
//      NRF24::printBuffer("request: ", buf, len);
      Serial.print("got request: ");
      Serial.println((char*)buf);
      
      // Send a reply
      uint8_t data[] = "And hello back to you";
      nrf24.send(data, sizeof(data));
      nrf24.waitPacketSent();
      Serial.println("Sent a reply");
    }
    else
    {
      Serial.println("recv failed");
    }
  }
}

Bu kod parçasındaki

if (nrf24.recv(buf, &len))

Bu satırda &len olan yerde *len şeklinde ve buf olan yerde *buf şeklinde yazılmasını bekliyordum. nrf24 örneğine ait recv fonksiyonunun dökümantasyonunda kullanımı

recv (uint8_t *buf, uint8_t *len)

şeklinde gözüküyor. *uint8_t veri tipinde bir bufferin adresini istiyor diye anlıyorum kullanıma bakınca fakat buf ı diğer değişken olarak veriyor. len i ise ne olarak verdiğini anlamamıştım fakat direk fonksiyonun kullanımına Buradaki linkten bakınca 2. parametredeki len değişkenine atama işlemi yapılacağından & işareti kullanıyoruz diye anladım. Ama hala neden buf u *buf olarak yazmadık anlayamadım. Lütfen bu konuda beni aydınlatın.

2

*len ifadesi len işaretçisinin gösterdiği hafızadaki değeri döndürür. len bir işaretçi değil, bu yüzden bu işlemi yapamazsınız.

Bu fonksiyonun deklarasyonu. recv isimli bir fonksiyonun argüman olarak iki tane uint8_t * aldığını söylüyor. uint8_t * bir tip: uint8_t işaretçisi.

*uint8_t diye bir veri tipi yok.

Bu örnekte buf bir uint8_t array’ı. Array’lar bazı şartlar altında otomatik olarak işaretçiye çevriliyor (buf → &buf[0]). Burada da buf, uint8_t *'e çevriliyor. recv fonksiyonunun istediği gibi.

* işareti solda olduğunda işaretçiyi takip edip değeri alır, sağda olduğunda ise bir veri tipini belirtir.

2 Beğeni